sandboxes = [
    'discritization_sandbox',
    'eos_sandbox',
    'finite_sandbox',
    'dimensions_sandbox',
    'quadrature_sandbox',
    'meta_sandbox',
    'mapping_sandbox'
]

expected_errors = {}
foreach entry : get_option('sandbox_expected_errors')
  parts = entry.split(':')
  if parts.length() != 2 or parts[0] not in sandboxes or parts[1] == ''
    error('Invalid sandbox_expected_errors entry: ' + entry)
  endif
  expected_errors += {parts[0]: parts[1]}
endforeach

foreach sandbox: sandboxes
  sandbox_exe = executable(
    sandbox,
    sandbox + '.cpp',
    dependencies: [serif_dep, stroid_dep, nameof_dep],
    build_rpath: mfem_runtime_prefix == '' ? '' : mfem_runtime_prefix / 'lib',
  )
  if expected_errors.has_key(sandbox)
    test(
      sandbox, python_build,
      args: [files('../../tools/check_sandbox_error.py'), sandbox_exe, expected_errors[sandbox]],
      workdir: meson.project_source_root(),
      suite: 'sandbox',
    )
  else
    test(sandbox, sandbox_exe, workdir: meson.project_source_root(), suite: 'sandbox')
  endif
endforeach